Makefile 0000644 0001751 0001752 00000000602 13363154043 010753 0 ustar www www webserver: webserver.ld webserver.o
$(LD) -s -T $^ -o $@
%.o: %.s
$(AS) $< -o $@
install: webserver
install webserver /var/www
setcap cap_net_bind_service=+eip /var/www/webserver
run: install
cd /var/www && find -type f ! -path ./webserver -printf '%P\0' | xargs -0 env -i chroot --userspec=www:www . /webserver
clean:
-rm -rf webserver.o webserver
.PHONY: clean run install
webserver.ld 0000644 0001751 0001752 00000000122 13363142313 011632 0 ustar www www ENTRY(_start);
SECTIONS {
. = 0x10000 + SIZEOF_HEADERS;
all : { *(*) }
}
webserver.s 0000644 0001751 0001752 00000026536 13412405520 011513 0 ustar www www # webserver implementation in x86_64 assembly
# for linux systems
# serves files provided on the command line
# at their location relative to the current
# directory, and index.html (if provided) at
# the root
.set NR_read, 0
.set NR_write, 1
.set NR_open, 2
.set NR_close, 3
.set NR_fstat, 5
.set NR_mmap, 9
.set NR_rt_sigaction, 13
.set NR_socket, 41
.set NR_accept4, 288
.set NR_bind, 49
.set NR_listen, 50
.set NR_setsockopt, 54
.set NR_exit, 60
.set stderr, 2
.set O_RDONLY, 0
.set PROT_READ, 1
.set MAP_PRIVATE, 2
.set SIGPIPE, 13
.set SIZEOF_STAT, 144
.set ST_SIZE, 48
.set SOCK_STREAM, 1
.set AF_INET, 2
.set IPPROTO_TCP, 6
.set TCP_DEFER_ACCEPT, 9
.set SOCK_NONBLOCK, 2048
.text
# entry point
.global _start
_start:
cmp $1, (%rsp)
jle print_usage
lea 8(%rsp), %rdi
# push a 0 onto the stack to mark
# end of loaded files
pushq $0
# loop through each argument
1:
add $8, %rdi
mov (%rdi), %rsi
# start the server at end of arguments
test %rsi, %rsi
jz start_server
# parse an option if arg begins with -
cmpb $'-', (%rsi)
je 2f
# load file and push details to the stack
call load_file
push %rax
push %rdx
push (%rdi)
jmp 1b
2:
call parse_option
jmp 1b
# parse a single-letter option
# and subsequent argument
parse_option:
cmpb $'a', 1(%rsi)
je set_address
cmpb $'p', 1(%rsi)
je set_port
jmp unknown_option
set_address:
add $8, %rdi
mov %rdi, %rbx
# parse first octet
mov (%rdi), %rdi
test %rdi, %rdi
jz invalid_address
call parse_int
cmpb $'.', (%rdi)
jne invalid_address
movb %al, sockaddr_address
# parse second octet
inc %rdi
call parse_int
cmpb $'.', (%rdi)
jne invalid_address
movb %al, sockaddr_address + 1
# parse third octet
inc %rdi
call parse_int
cmpb $'.', (%rdi)
jne invalid_address
movb %al, sockaddr_address + 2
# parse fourth octet
inc %rdi
call parse_int
cmpb $0, (%rdi)
jne invalid_address
movb %al, sockaddr_address + 3
# restore %rdi and return
mov %rbx, %rdi
ret
invalid_address:
mov $stderr, %rdi
mov $invalid_address_str, %rsi
mov $invalid_address_strlen, %rdx
call write_all
mov $1, %rdi
jmp exit
set_port:
add $8, %rdi
mov %rdi, %rbx
# parse port and write in big endian
mov (%rdi), %rdi
test %rdi, %rdi
jz invalid_port
call parse_int
mov %ah, sockaddr_port
mov %al, sockaddr_port + 1
mov %rbx, %rdi
ret
invalid_port:
mov $stderr, %rdi
mov $invalid_port_str, %rsi
mov $invalid_port_strlen, %rdx
call write_all
mov $1, %rdi
jmp exit
# mmap the file with filename in %rsi
# return pointer to file data in %rax
# return file length in %rdx
load_file:
mov %rsi, %r12
# open
mov $NR_open, %rax
mov %rdi, %rbx
mov %rsi, %rdi
mov $O_RDONLY, %rsi
syscall
test %rax, %rax
js load_failed
# stat
mov %rax, %rdi
mov $NR_fstat, %rax
sub $SIZEOF_STAT, %rsp
mov %rsp, %rsi
syscall
test %rax, %rax
js stat_failed
# mmap
mov %rdi, %r8
mov ST_SIZE(%rsp), %rsi
add $SIZEOF_STAT, %rsp
mov $NR_mmap, %rax
xor %edi, %edi
mov $PROT_READ, %rdx
mov $MAP_PRIVATE, %r10
xor %r9, %r9
syscall
test %rax, %rax
js mmap_failed
# close original fd
mov %rax, %rdx
mov $NR_close, %rax
mov %r8, %rdi
syscall
test %rax, %rax
js close_failed
# restore rdi and return
mov %rbx, %rdi
mov %rdx, %rax
mov %rsi, %rdx
ret
load_failed:
mov $load_failed_str, %r9
mov $load_failed_strlen, %rdx
jmp 1f
stat_failed:
mov $stat_failed_str, %r9
mov $stat_failed_strlen, %rdx
jmp 1f
mmap_failed:
mov $mmap_failed_str, %r9
mov $mmap_failed_strlen, %rdx
jmp 1f
close_failed:
mov $close_failed_str, %r9
mov $close_failed_strlen, %rdx
#jmp 1f
1:
mov %rsi, %rbx
mov %r9, %rsi
mov $stderr, %rdi
call write_all
mov %r12, %rsi
call write_ztstr
mov $NR_write, %rax
mov $stderr, %rdi
mov $newline, %rsi
mov $1, %rdx
syscall
mov $1, %rdi
jmp exit
# create a socket, listen and accept connections
start_server:
# ignore SIGPIPE signal
mov $NR_rt_sigaction, %rax
mov $SIGPIPE, %rdi
mov $sigaction, %rsi
xor %edx, %edx
mov $8, %r10
syscall
test %rax, %rax
js sigaction_failed
# socket
mov $NR_socket, %rax
mov $AF_INET, %rdi
mov $SOCK_STREAM, %rsi
xor %edx, %edx
syscall
test %rax, %rax
js socket_failed
# set TCP_DEFER_ACCEPT
mov %rax, %rdi
mov $NR_setsockopt, %rax
mov $IPPROTO_TCP, %rsi
mov $TCP_DEFER_ACCEPT, %rdx
mov $defer_accept_timeout, %r10
mov $4, %r8
syscall
test %rax, %rax
js setsockopt_failed
# bind
mov $NR_bind, %rax
mov $sockaddr, %rsi
mov $sockaddr_len, %rdx
syscall
test %rax, %rax
js bind_failed
# listen
mov $NR_listen, %rax
mov $128, %rsi
syscall
test %rax, %rax
js listen_failed
1:
# accept
mov $NR_accept4, %rax
xor %esi, %esi
xor %edx, %edx
mov $SOCK_NONBLOCK, %r10
syscall
test %rax, %rax
js accept_failed
# read
sub $0x400, %rsp
mov %rdi, %rbx
mov %rax, %rdi
mov $NR_read, %rax
mov %rsp, %rsi
mov $0x400, %rdx
syscall
cmp $5, %rax
jle 3f
# store end of request in r11
lea (%rsp, %rax, 1), %r11
# check for HTTP GET request
cmpl $0x20544547, (%rsp) # "GET "
jne 3f
lea 0x3e8(%rsp), %rbp
mov %rdi, %r9
# compare each loaded filename with the request
2:
add $24, %rbp
mov (%rbp), %rdi
test %rdi, %rdi
jz 404f
mov $-1, %rcx
# get length of loaded filename in %rcx
xor %eax, %eax
repnz scasb (%rdi), %al
not %rcx
dec %rcx
# compare request with filename
mov (%rbp), %rdi # get filename in %rdi
lea 5(%rsp), %rsi # get request in %rsi; skip the "GET /"
mov $index_html, %r10
cmpb $' ', (%rsi) # check for root request
cmove %r10, %rsi # use "index.html" if root request
repe cmpsb (%rdi), (%rsi) # do the comparison
jne 2b # strings do not match
cmpb $' ', (%rsi) # request terminated by space
jne 2b # strings not same length
cmp %r11, %rsi
ja 2b # read past the end of the request
# write 200 OK message
mov %r9, %rdi
mov $http_200_str, %rsi
mov $http_200_strlen, %rdx
call write_all
# write file data
mov 16(%rbp), %rsi
mov 8(%rbp), %rdx
call write_all
jmp 3f
404:
# write 404 not found error
mov %r9, %rdi
mov $http_404_str, %rsi
mov $http_404_strlen, %rdx
call write_all
#jmp 3f
3:
# close
mov %r9, %rdi
mov $NR_close, %rax
syscall
add $0x400, %rsp
mov %rbx, %rdi
jmp 1b
sigaction_failed:
mov $sigaction_failed_str, %r9
mov $sigaction_failed_strlen, %rdx
jmp 1f
socket_failed:
mov $socket_failed_str, %r9
mov $socket_failed_strlen, %rdx
jmp 1f
setsockopt_failed:
mov $setsockopt_failed_str, %r9
mov $setsockopt_failed_strlen, %rdx
jmp 1f
bind_failed:
mov $bind_failed_str, %r9
mov $bind_failed_strlen, %rdx
jmp 1f
listen_failed:
mov $listen_failed_str, %r9
mov $listen_failed_strlen, %rdx
jmp 1f
accept_failed:
mov $accept_failed_str, %r9
mov $accept_failed_strlen, %rdx
#jmp 1f
1:
mov %rsi, %rbx
mov %r9, %rsi
mov $stderr, %rdi
call write_all
mov $1, %rdi
jmp exit
# parse an string as decimal integer
# stop when character is non-digit
parse_int:
xor %eax, %eax
xor %edx, %edx
1:
movb (%rdi), %dl
cmpb $'0', %dl
jb 2f
cmpb $'9', %dl
ja 2f
sub $'0', %dl
lea (%rax, %rax, 4), %rax
lea (%rdx, %rax, 2), %rax
inc %rdi
jmp 1b
2:
ret
# print debug message for unsupported flags
unknown_option:
mov %rsi, %rbx
mov $stderr, %rdi
mov $unknown_str, %rsi
mov $unknown_strlen, %rdx
call write_all
mov %rbx, %rsi
mov $2, %rdx
call write_all
mov $NR_write, %rax
mov $newline, %rsi
mov $1, %rdx
syscall
# jmp print_usage
# print usage message
print_usage:
mov $stderr, %rdi
mov $usage_str, %rsi
mov $usage_strlen, %rdx
call write_all
mov $1, %rdi
jmp exit
# write a zero-terminated string in %rsi to the file in %rdi
write_ztstr:
xor %eax, %eax
mov %rdi, %r9
mov %rsi, %rdi
mov $-1, %rcx
repnz scasb (%rdi), %al
not %rcx
dec %rcx
mov %r9, %rdi
mov %rcx, %rdx
# jmp write_all
# write bytes to file in $rdi until all have been written
# or a failure occurs
write_all:
1:
mov $NR_write, %rax
syscall
test %rax, %rax
js 2f
add %rax, %rsi
sub %rax, %rdx
test %rdx, %rdx
jnz 1b
2:
ret
# exit with the status code in %rdi
exit:
mov $NR_exit, %rax
syscall
.section .rodata
sigaction:
.quad 1 # sa_handler = SIG_IGN
.quad 0 # sa_flags = 0
.quad 0 # sa_restorer = 0
.quad 0 # sa_mask = 0
defer_accept_timeout:
.int 10
unknown_str:
.ascii "webserver: unknown option: "
.set unknown_strlen, . - unknown_str
invalid_address_str:
.ascii "webserver: invalid address\n"
.set invalid_address_strlen, . - invalid_address_str
invalid_port_str:
.ascii "webserver: invalid port\n"
.set invalid_port_strlen, . - invalid_port_str
load_failed_str:
.ascii "webserver: failed to load file: "
.set load_failed_strlen, . - load_failed_str
stat_failed_str:
.ascii "webserver: failed to stat file: "
.set stat_failed_strlen, . - stat_failed_str
mmap_failed_str:
.ascii "webserver: failed to mmap file: "
.set mmap_failed_strlen, . - mmap_failed_str
close_failed_str:
.ascii "webserver: failed to close file: "
.set close_failed_strlen, . - close_failed_str
sigaction_failed_str:
.ascii "webserver: ignoring SIGPIPE failed\n"
.set sigaction_failed_strlen, . - sigaction_failed_str
socket_failed_str:
.ascii "webserver: failed to create socket\n"
.set socket_failed_strlen, . - socket_failed_str
setsockopt_failed_str:
.ascii "webserver: failed to set socket options\n"
.set setsockopt_failed_strlen, . - setsockopt_failed_str
bind_failed_str:
.ascii "webserver: failed to bind to socket address\n"
.set bind_failed_strlen, . - bind_failed_str
listen_failed_str:
.ascii "webserver: failed to listen on socket\n"
.set listen_failed_strlen, . - listen_failed_str
accept_failed_str:
.ascii "webserver: failed to accept remote connection\n"
.set accept_failed_strlen, . - accept_failed_str
index_html:
.ascii "index.html"
.ascii " "
.byte 0
http_200_str:
.ascii "HTTP/1.1 200 OK\r\n"
.ascii "Connection: close\r\n"
.ascii "\r\n"
.set http_200_strlen, . - http_200_str
http_404_str:
.ascii "HTTP/1.1 404 Not Found\r\n"
.ascii "Connection: close\r\n"
.ascii "\r\n"
.ascii ""
.ascii ""
.ascii ""
.ascii "404 Not Found
"
.ascii ""
.set http_404_strlen, . - http_404_str
newline:
.ascii "\n"
usage_str:
.ascii "USAGE: webserver [-a address] [-p port] file...\n"
.ascii " Listen for incoming connections at address:port\n"
.ascii " and serve the given files over http.\n"
.ascii " As a special case, serve index.html (if provided)\n"
.ascii " at the root.\n"
.set usage_strlen, . - usage_str
.data
sockaddr:
sockaddr_family: .short AF_INET
sockaddr_port: .byte 0, 80
sockaddr_address: .int 0
sockaddr_pad: .quad 0
.set sockaddr_len, . - sockaddr